ACTOR WickedMissile : FastProjectile
{
  Speed 250
  Radius 3
  Height 8
  Damage 20
  MissileHeight 8
  +RIPPER
  +CANNOTPUSH
  +NODAMAGETHRUST
  +FORCEXYBILLBOARD
  // +SPAWNSOUNDSOURCE
  MissileType "WickedSmoke"
  DamageType "Fire"
  Obituary "%o was cooked alive."
  States
  {
  Spawn:
    TNT1 A 2 Bright
    Loop
  Death:
	FRBL CDEFGHI 1 Bright
    Stop
  }
}

ACTOR WickedSmoke
{
  +NOBLOCKMAP
  +NOGRAVITY
  +SHADOW
  +NOTELEPORT
  +CANNOTPUSH
  +NODAMAGETHRUST
  +FORCEXYBILLBOARD
  RenderStyle Add
  Alpha 0.6
  Scale 0.75
  States
  {
  Spawn:
	CKFX A 0
	//CKFX A 0 A_SpawnItemEx("WickedSmokeLong",0,0,0)
	CKFX A 0 A_SpawnItemEx("WickedSmokeHuge",0,0,0)
	CKFX A 0 A_SpawnItemEx("WickedSmokeHuge",12,0,0)
	CKFX A 0 A_SpawnItemEx("WickedSmokeHuge",-12,0,0)
    FRBL CCDDEEFFGGHHII 1 bright A_FadeOut(0.05)
    Stop
  }
}

ACTOR WickedSmokeLong : WickedSmoke
{
	Scale 0.3
	States
	{
		Spawn:
		FRBL ABABAB 2 Bright
		FRBL CCDDEEFFGGHHII 1 bright A_FadeOut(0.05)
		Stop
	}
}

ACTOR WickedSmokeHuge : WickedSmoke
{
	Scale 1.5
	Alpha 0.2
	States
  {
  Spawn:
	CKFX A 0
    FRBL CCDDEEFFGGHHII 1 bright A_FadeOut(0.03)
    Stop
  }
}

ACTOR WickedPrimary : Ammo
{
  Inventory.Amount 1
  Inventory.MaxAmount 15
  Ammo.BackpackAmount 1
  Ammo.BackpackMaxAmount 15
  Inventory.Icon "SKSTH0"
}

ACTOR WickedStaff : DoomWeapon
{
  Weapon.SelectionOrder 2500
  Weapon.AmmoUse 1
  Weapon.AmmoGive 5
  Weapon.AmmoType "WickedPrimary"
  +WEAPON.NOAUTOFIRE
  Inventory.PickupMessage "You picked up the Wicked Staff."
  Tag "Wicked Staff"
  Weapon.BobStyle Smooth
  Weapon.BobSpeed 2.5
  Weapon.BobRangeX 0.5
  Weapon.BobRangeY 0.3
  States
  {
  Ready:
	WKSI A 0
	WKSI A 0 A_Jump(255,"Ready1","Ready2","Ready3")
	Goto Ready1
	
  Ready1:
    WKSI I 1 A_WeaponReady
    Goto Ready
  Ready2:
    WKSI J 1 A_WeaponReady
    Goto Ready
  Ready3:
    WKSI K 1 A_WeaponReady
    Goto Ready
  Deselect:
	WKSI GFEDCBA 1
	TNT1 AAAAAAAAAAAAAAA 0 A_Lower
    TNT1 A 1 A_Lower
    Goto Deselect+7
  Select:
	TNT1 A 0 A_SetCrosshair(16)
	TNT1 A 0
	TNT1 A 1 A_WeaponReady
    Goto SelectAnim
  SelectAnim:
	WKSI ABCDEFGH 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Ready
  Fire:
	MISG B 0 A_PlayWeaponSound("wicked/fire")
	WKSI IJ 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	MISG B 0 A_Recoil(5)
    MISG B 0 A_FireCustomMissile("WickedMissile",1,1,14)
	MISG B 0 A_FireCustomMissile("WickedMissile",4,0,14)
	MISG B 0 A_FireCustomMissile("WickedMissile",-2,0,14)
	MISG B 0 A_FireCustomMissile("WickedMissile",7,0,14)
	MISG B 0 A_FireCustomMissile("WickedMissile",-5,0,14)
	MISG B 0 A_SetPitch(Pitch-2.0)
	PPFI A 0 A_FireCustomMissile("ShakeYourAssQuad",0,0)
	PPFI A 0 A_FireCustomMissile("SplayerMuzzleFX",0,0,8)
	TNT1 A 0 A_SpawnItemEx("ShooterLight",0,0,0)
	WKSI MNOP 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	WKSI QRSTUV 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
    Goto Ready
  Spawn:
    SKST G -1
    Stop
  }
}