ACTOR PlayerVoice : Inventory
{
	Inventory.MaxAmount 99
}

ACTOR IsParrying : Inventory
{
	Inventory.MaxAmount 1
}

ACTOR CurrentTab : Inventory
{
	Inventory.MaxAmount 99
}

ACTOR CurrentTabHover : Inventory
{
	Inventory.MaxAmount 99
}

ACTOR TauntTimer : Inventory
{
	Inventory.MaxAmount 999
}

ACTOR IsCrouched : Inventory
{
	Inventory.MaxAmount 1
}

ACTOR PendingQuickness : Inventory
{
	Inventory.MaxAmount 1
}

ACTOR Action_Pay : CustomInventory
{
	Inventory.Amount 1
	Inventory.MaxAmount 1
	-INVBAR
	+INVENTORY.UNDROPPABLE

	States
	{
	Spawn:
	TNT1 A 1
	Loop
	Use:
	TNT1 A 0 A_JumpIfInventory("Money",50,1)
	Fail
	//TNT1 A 0 A_SpawnItemEx("ThrownMoney",10,0,30,16,0,0)
	TNT1 A 0 A_FireCustomMissile("ThrownMoney",0,0)
	TNT1 A 0 A_TakeInventory("Money",50)
	Fail
	}
}


ACTOR PlayerStepSound
{
 radius 1
 height 1
 +NOCLIP
 +CLIENTSIDEONLY
 States
 {
 Spawn:
  TNT1 A 0
  TNT1 A 1 A_PlaySoundEx("step/concrete","Weapon")
  stop
 }
}

ACTOR ZTPlayer : DoomPlayer
{
  Speed 1
  Health 100
  Radius 16
  Height 56
  Mass 200
  PainChance 255
  -TELESTOMP
  +DONTBLAST
  Player.DisplayName "Zombie Hunter"
  Player.StartItem "OrderSecondary", 50
  Player.StartItem "Action_Reload"
  Player.StartItem "Action_Block"
  Player.StartItem "Action_TertiaryFire"
  Player.StartItem "Action_FuckOff"
  Player.StartItem "Action_QuickGrenade"
  Player.StartItem "Action_SwitchAmmo"
  Player.StartItem "MenuWeapon"
  Player.StartItem "Action_Pay"
  Player.Soundclass "zomb"
  Player.ForwardMove 0.8
  Player.SideMove 0.8
  DamageFactor "ItemExplode", 0.0
  DamageFactor "PulverizerBoom", 0.0

  States
  {
  Spawn:
  Idling:
	PLR1 A 0 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 E 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking")
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"IdlingPistol")
	PLR1 D 1
    Loop
  Jumper:
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"JumperPistol")
	PLR1 E 1
	PLR1 E 0 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 E 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"See")
	Goto Idling
  See:
  Walking:
	PLR1 A 0 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"WalkingPistol")
    PLR1 BBBBBB 1 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 A 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking2")
	Goto Idling
  Walking2:
	PLR1 A 0 A_JumpIf(z-floorz > 16,"Jumper")
    PLR1 C 0 A_JumpIf (z - floorz > 0, 2)
	PLR1 C 0 A_SpawnItemEx("PlayerStepSound", -1, -1, 0, 0, 0, 0, 0, 128, 0)
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"Walking2Pistol")
	PLR1 CCCCCC 1 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 C 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking3")
	Goto Idling
  Walking3:
	PLR1 A 0 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"Walking3Pistol")
	PLR1 BBBBBB 1 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 D 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking4")
	Goto Idling
  Walking4:
	PLR1 A 0 A_JumpIf(z-floorz > 16,"Jumper")
    PLR1 A 0 A_JumpIf (z - floorz > 0, 2)
    PLR1 A 0 A_SpawnItemEx("PlayerStepSound", -1, 1, 0, 0, 0, 0, 0, 128, 0)
	PLR1 D 0 A_JumpIfInventory("WTypePistol",1,"Walking4Pistol")
	PLR1 AAAAAA 1 A_JumpIf(z-floorz > 16,"Jumper")
	PLR1 A 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking")
    Goto Idling
  Missile:
    PLR1 A 0
    Goto Idling
  Melee:
    PLR1 A 0
    Goto Idling
  Pain:
	PLR1 G 0 ACS_ExecuteAlways(820,0,2,0,0)
    Goto Idling
  Death:
	PLPC F 0 A_PlayerScream
    PLPC F 4
	PLPC G 8 A_NoBlocking
    PLPC HI 4
    PLPC J -1
    Stop
  Death.ExplosiveDamage:
    TNT1 A 0 A_SpawnItemEx("GibChunkSpawner",0,0,32)
	BSZM MNOPQR 1
	BSZM S -1
	Stop
	
	
	
	//--==--==--==--==--==--==--==--==
	// standard pistol
	//--==--==--==--==--==--==--==--==
	IdlingPistol:
		PLR2 D 1
		Goto Idling
	JumperPistol:
		PLR2 E 1
		PLR2 E 0 A_JumpIf(z-floorz > 16,"Jumper")
		PLR2 E 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"See")
		Goto Idling
	WalkingPistol:
		PLR2 BBBBBB 1 A_JumpIf(z-floorz > 16,"Jumper")
		PLR2 A 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking2")
		Goto Idling
	Walking2Pistol:
		PLR2 CCCCCC 1 A_JumpIf(z-floorz > 16,"Jumper")
		PLR2 C 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking3")
		Goto Idling
	Walking3Pistol:
		PLR2 BBBBBB 1 A_JumpIf(z-floorz > 16,"Jumper")
		PLR2 D 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking4")
		Goto Idling
	Walking4Pistol:
		PLR2 AAAAAA 1 A_JumpIf(z-floorz > 16,"Jumper")
		PLR2 A 0 A_JumpIf((MomX*MomX)+(MomY*MomY) > 20,"Walking")
		Goto Idling
  }
}