ACTOR Katana : Weapon
{
  +WEAPON.NOAUTOAIM
  Weapon.Kickback 100
  Obituary "%k sliced %o into pork cutlets with a katana."
  Tag "Machete"
  +WEAPON.MELEEWEAPON
  +WEAPON.NOALERT
  Weapon.BobStyle Smooth
  Weapon.BobSpeed 2.5
  Weapon.BobRangeX 0.5
  Weapon.BobRangeY 0.3
  States
  {
  Ready:
	PPSS A 0 //A_JumpIfInventory("QuickGrenading",1,"ToGrenade")
    KATA A 1 A_WeaponReady
    Goto Ready
  Deselect:
	 MCSS CBA 1
     TNT1 AAAAAAAAAA 0 A_Lower
	 TNT1 A 1 A_Lower
     Goto Deselect+3
  Select:
	 TNT1 A 0 A_SetCrosshair(16)
	 TNT1 AA 0 A_Raise
	 TNT1 A 1 A_WeaponReady
	 TNT1 A 0 A_PlaySoundEx("cloth/melee","SoundSlot6")
	 Goto SelectAnim
  SelectAnim:
	 KATS ABC 1 A_WeaponReady(WRF_NOFIRE | WRF_NOSWITCH)
	 Goto Ready
  Fire:
	PUNG A 0
	KATA A 1
	PUNG A 0 A_JumpIf(0 == (ACS_ExecuteWithResult(559,0,0,0)), "SlashLeft")
	PUNG A 0 A_JumpIf(1 == (ACS_ExecuteWithResult(559,0,0,0)), "SlashRight")
	PUNG A 0 A_JumpIf(2 == (ACS_ExecuteWithResult(559,0,0,0)), "SlashDown")
	Goto SlashDown
  SlashLeft:
	KATA BCD 1 A_SetAngle(Angle+2.0)
	KATA A 0 A_PlaySoundEx("katana/fire","Weapon")
	KATL ABCDE 1 A_SetAngle(Angle-1.5)
	MCFI H 0 A_CustomPunch(2*random(1, 10), TRUE, 0, "ZTLeftPuff", 128)
	KATL FGHI 1 A_SetAngle(Angle-1.5)
	Goto SelectAnim
  SlashRight:
	KATA BCD 1 A_SetAngle(Angle-2.0)
	KATA A 0 A_PlaySoundEx("katana/fire","Weapon")
	KATR ABCDE 1 A_SetAngle(Angle+1.5)
	MCFI H 0 A_CustomPunch(2*random(1, 10), TRUE, 0, "ZTRightPuff", 128)
	KATR FGHI 1 A_SetAngle(Angle+1.5)
	Goto SelectAnim
  SlashDown:
    KATA BCD 1 A_SetPitch(Pitch-4.0)
	KATA A 0 A_PlaySoundEx("katana/fire","Weapon")
	KATD ABCD 1 A_SetPitch(Pitch+3.0)
	MCFI H 0 A_CustomPunch(2*random(1, 2), TRUE, 0, "ZTVertPuff", 128)
	KATD E 1 A_SetPitch(Pitch+2.0)
	MCFI H 0 A_CustomPunch(2*random(1, 2), TRUE, 0, "ZTVertPuff", 128)
	KATD F 1 A_SetPitch(Pitch+1.0)
	MCFI H 0 A_CustomPunch(2*random(1, 2), TRUE, 0, "ZTVertPuff", 128)
	KATD G 1 A_SetPitch(Pitch+0.5)
	MCFI H 0 A_CustomPunch(2*random(1, 2), TRUE, 0, "ZTVertPuff", 128)
	KATD H 1 A_SetPitch(Pitch+0.25)
	Goto SelectAnim
	
  }
}