//==-----------------------------------------==
// R A V A G E R   A M M U N I T I O N
//
// Maximum unperked is 100
// Gun 1: > 9
// Gun 2: <= 6
// Gun 3: <= 3
// Gun 4: <= 0
//
// Hand 1: > 97
// Hand 2: <= 97
// Hand 3: <= 94
// Hand 4: <= 91
// Hand 5: <= 88
//==-----------------------------------------==

// Controls raising and lowering the left hand
ACTOR HideLeftHand : Inventory { Inventory.MaxAmount 1}

ACTOR RavagerPrimary : Ammo
{
  Inventory.Amount 0
  Inventory.MaxAmount 150
  Ammo.BackpackAmount 0
  Ammo.BackpackMaxAmount 150
  +IGNORESKILL
  Inventory.Icon "CLIPA0"
}

ACTOR RavagerSecondary : Ammo
{
  Inventory.Amount 25
  Inventory.MaxAmount 300
  Ammo.BackpackAmount 25
  Ammo.BackpackMaxAmount 300
  +IGNORESKILL
  Inventory.Icon "CLIPA0"
}

ACTOR "SS-2 Ravager" : Weapon
{
  +WEAPON.NOAUTOAIM
  Weapon.BobStyle Smooth
  Weapon.BobSpeed 2.5
  Weapon.BobRangeX 0.5
  Weapon.BobRangeY 0.3
   Weapon.SelectionOrder 100
   Weapon.AmmoUse 1
   Weapon.AmmoGive2 100
   Weapon.AmmoType "RavagerPrimary"
   Weapon.AmmoType2 "RavagerSecondary"
   Inventory.PickupMessage "You got the SS-2 Ravager Yes!" // "You got the chaingun"
   Inventory.PickupSound "m60/boltfwd"
   Obituary "%o was mowed down by %k's Ravager"
   Tag "SS-2 Ravager"
   Scale 0.4
   States
   {
   Deselect:
	 TNT1 A 0
     Goto DeselectAnim
   Select:
	 TNT1 A 0 A_Raise
	 Goto SelectAnim
	 
//==========================================================
// -- SELECT
//==========================================================

  SelectAnim:
	TNT1 A 0 A_PlaySoundEx("m60/deploy","SoundSlot5")
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	TNT1 A 0 A_GunFlash("SelectHand")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",9,"Select1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",6,"Select2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",3,"Select3")
	Goto Select4
	
  // GUN - 9 bullets
  Select1:
	M6S1 ABCDEFGH 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
	Goto Ready
  // GUN - 6 bullets
  Select2:
	M6S2 ABCDEFGH 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
	Goto Ready
  // GUN - 3 bullets
  Select3:
	M6S3 ABCDEFGH 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
	Goto Ready
  // GUN - 0 bullets
  Select4:
	M6S4 ABCDEFGH 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
	Goto Ready
	
	
	
  SelectHand:
	TNT1 AAAA 1
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",97,"SelectHand1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",94,"SelectHand2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",91,"SelectHand3")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",88,"SelectHand4")
	Goto SelectHand5
	
  // HAND - 97 bullets
  SelectHand1:
	H6S1 ABCD 1
	Goto ReadyHand
  // HAND - 94 bullets
  SelectHand2:
	H6S2 ABCD 1
	Goto ReadyHand
  // HAND - 91 bullets
  SelectHand3:
	H6S3 ABCD 1
	Goto ReadyHand
  // HAND - 88 bullets
  SelectHand4:
	H6S4 ABCD 1
	Goto ReadyHand
  // HAND - Less than 88 bullets
  SelectHand5:
	// H6S5 ABCD 1
	TNT1 A 1
	Goto ReadyHand
	
//==========================================================
// -- DESELECT
//==========================================================

  DeselectAnim:
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	TNT1 A 0 A_GunFlash("SelectHand")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",9,"Deselect1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",6,"Deselect2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",3,"Deselect3")
	Goto Deselect4
	
  // GUN - 9 bullets
  Deselect1:
	M6S1 FEDCBA 1
	Goto ReallyLower
  // GUN - 6 bullets
  Deselect2:
	M6S2 FEDCBA 1
	Goto ReallyLower
  // GUN - 3 bullets
  Deselect3:
	M6S3 FEDCBA 1
	Goto ReallyLower
  // GUN - 0 bullets
  Deselect4:
	M6S4 FEDCBA 1
	Goto ReallyLower
  ReallyLower:
	TNT1 AAAAAAAAAA 0 A_Lower
	TNT1 A 1 A_Lower
	Loop
	
	
	
  DeselectHand:
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",97,"DeselectHand1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",94,"DeselectHand2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",91,"DeselectHand3")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",88,"DeselectHand4")
	Goto DeselectHand5
	
  // HAND - 97 bullets
  DeselectHand1:
	H6S1 DCBA 1
	Goto NullHand
  // HAND - 94 bullets
  DeselectHand2:
	H6S2 DCBA 1
	Goto NullHand
  // HAND - 91 bullets
  DeselectHand3:
	H6S3 DCBA 1
	Goto NullHand
  // HAND - 88 bullets
  DeselectHand4:
	H6S4 DCBA 1
	Goto NullHand
  // HAND - Less than 88 bullets
  DeselectHand5:
	// H6S5 ABCD 1
	TNT1 A 1
	Goto NullHand
  NullHand:
	TNT1 A 1
	Stop

//==========================================================
// -- IDLING
//==========================================================

  Ready:
	PPSS A 0 //A_JumpIfInventory("DoBlocking",1,"QuickMelee")
	PPSS A 0 A_JumpIfInventory("IsReloading",1,"ReloadCheck")
	PPSS A 0 //A_JumpIfInventory("QuickGrenading",1,"ToGrenade")
    TNT1 A 0 A_JumpIfInventory("RavagerPrimary",9,"Ready1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",6,"Ready2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",3,"Ready3")
	Goto Ready4
	
  // GUN - 9 bullets
  Ready1:
	M6I1 A 1 A_WeaponReady
	Goto Ready
  // GUN - 6 bullets
  Ready2:
	M6I2 A 1 A_WeaponReady
	Goto Ready
  // GUN - 3 bullets
  Ready3:
	M6I3 A 1 A_WeaponReady
	Goto Ready
  // GUN - 0 bullets
  Ready4:
	M6I4 A 1 A_WeaponReady
	Goto Ready
	
	
	
  ReadyHand:
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",97,"ReadyHand1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",94,"ReadyHand2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",91,"ReadyHand3")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",88,"ReadyHand4")
	Goto ReadyHand5
	
  ReadyHand1:
	H6I1 A 1 A_TakeInventory("HideLeftHand",1)
	Goto ReadyHand
  ReadyHand2:
	H6I2 A 1 A_TakeInventory("HideLeftHand",1)
	Goto ReadyHand
  ReadyHand3:
	H6I3 A 1 A_TakeInventory("HideLeftHand",1)
	Goto ReadyHand
  ReadyHand4:
	H6I4 A 1 A_TakeInventory("HideLeftHand",1)
	Goto ReadyHand
  ReadyHand5:
	// H6I5 A 1
	TNT1 A 1
	Goto ReadyHand
	
 //========================================================================
 // RELOAD CHECKING
 //========================================================================
  
  ReloadCheck:
	 TNT1 A 0 A_TakeInventory("IsReloading",1)
	 TNT1 A 0 A_JumpIfInventory("Perk_Commando",1,"ReloadCheckPerk")
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",100,"Ready")
	 TNT1 A 0 A_JumpIfInventory("RavagerSecondary",11,"Eject")
	 Goto Ready
	
  ReloadCheckPerk:
	 TNT1 A 0 A_JumpIfInventory("PerkLevel",10,"ReloadCheckPerk10")
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",125,"Ready")
	 TNT1 A 0 A_JumpIfInventory("RavagerSecondary",11,"Eject")
	 Goto Ready
	 
  ReloadCheckPerk10:
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",150,"Ready")
	 TNT1 A 0 A_JumpIfInventory("RavagerSecondary",11,"Eject")
	 Goto Ready
  
//==========================================================
// -- FIRING
//==========================================================

  // Perform a special exception if the hand is going to
  // run out of bullets to hold
  Fire:
	TNT1 A 0
	Goto FireStart
  FireStart:
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",98,"DoHandFlash")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",95,"DoHandFlash")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",92,"DoHandFlash")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",89,"DoHandFlash")
	Goto SpecialFlash
	
  DoHandFlash:
	TNT1 A 0 A_GunFlash("FireHand")
	Goto ActualFire
  // Hand doesn't have any bullets left to hold, flash ONLY if it's shown
  SpecialFlash:
	TNT1 A 0 A_JumpIfInventory("HideLeftHand",1,"ActualFire")
	TNT1 A 0 A_GunFlash("FireHand")
	Goto ActualFire
	
  ActualFire:
	PPFI A 0 A_FireCustomMissile("MuzzleSmokeFX",0,0,4,0)
	TNT1 A 0 A_PlayWeaponSound("m60/fire")
	BPSS A 0 A_FireCustomMissile("LongRifleCaseSpawn",5,0,20,-3)
	BPSS A 0 A_FireCustomMissile("BlackLinkSpawn",5,0,20,-3)
	EXP1 A 0 A_PlaySoundEx("m60/distant","SoundSlot6")
	EXP1 A 0 A_Recoil(1.0)
	TNT1 A 0 A_SpawnItemEx("ShooterLight",0,0,0)
	BPSS A 0 A_JumpIfInventory("Perk_Commando",1,"FireFXPerk")
	Goto FireFX
  FireFX:
	TNT1 A 0 A_FireBullets(5.6, 5.6, 1, 30, "BulletPuff2")
	PPFI A 0 A_FireCustomMissile("ShakeYourAssDouble",0,0)
	TNT1 A 0 A_SetPitch(Pitch-5.0)
	Goto FireJump
  FireFXPerk:
	TNT1 A 0 A_FireBullets(2.6, 2.6, 1, 30, "BulletPuff2")
	PPFI A 0 A_FireCustomMissile("ShakeYourAss",0,0)
	TNT1 A 0 A_SetPitch(Pitch-2.5)
	Goto FireJump
  FireJump:
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",9,"Fire1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",6,"Fire2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",3,"Fire3")
	Goto Fire4
	
  // GUN - 9 bullets
  Fire1:
	TNT1 A 0 A_Jump(255,"Fire1_1","Fire1_2","Fire1_3")
	Goto Fire1_1
  Fire1_1:
	M6F1 A 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire1End
  Fire1_2:
	M6F1 B 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire1End
  Fire1_3:
	M6F1 C 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire1End
  Fire1End:
	M6F1 DEF 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6F1 A 0 A_Refire("FireStart")
	Goto Ready
	
  // GUN - 6 bullets
  Fire2:
	TNT1 A 0 A_Jump(255,"Fire2_1","Fire2_2","Fire2_3")
	Goto Fire2_1
  Fire2_1:
	M6F2 A 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire2End
  Fire2_2:
	M6F2 B 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire2End
  Fire2_3:
	M6F2 C 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire2End
  Fire2End:
	M6F2 DEF 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6F2 A 0 A_Refire("FireStart")
	Goto Ready
	
  // GUN - 3 bullets
  Fire3:
	TNT1 A 0 A_Jump(255,"Fire3_1","Fire3_2","Fire3_3")
	Goto Fire3_1
  Fire3_1:
	M6F3 A 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire3End
  Fire3_2:
	M6F3 B 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire3End
  Fire3_3:
	M6F3 C 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire3End
  Fire3End:
	M6F3 DEF 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6F3 A 0 A_Refire("FireStart")
	Goto Ready
	
  // GUN - 0 bullets
  Fire4:
	TNT1 A 0 A_Jump(255,"Fire4_1","Fire4_2","Fire4_3")
	Goto Fire4_1
  Fire4_1:
	M6F4 A 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire4End
  Fire4_2:
	M6F4 B 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire4End
  Fire4_3:
	M6F4 C 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Fire4End
  Fire4End:
	M6F4 DEF 1 bright A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6F4 A 0 A_Refire("FireStart")
	Goto Ready
	
	
	
  FireHand:
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",98,"FireHand1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",95,"FireHand2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",92,"FireHand3")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",89,"FireHand4")
	Goto FireHand5
  FireHand1:
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	H6F1 AAB 1
	Goto ReadyHand
  FireHand2:
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	H6F2 AAB 1
	Goto ReadyHand
  FireHand3:
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	H6F3 AAB 1
	Goto ReadyHand
  FireHand4:
	TNT1 A 0 A_TakeInventory("HideLeftHand",1)
	H6F4 AAB 1
	Goto ReadyHand
  FireHand5:
	H6F5 A 0 A_GiveInventory("HideLeftHand",1)
	H6F5 ABC 1
	Goto ReadyHand
	
//==========================================================
// -- PRE-RELOAD EJECT
//==========================================================
  Eject:
	9MRL A 0 ACS_ExecuteAlways(820,0,0,0,0)
    TNT1 A 0 A_JumpIfInventory("RavagerPrimary",9,"Eject1")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",6,"Eject2")
	TNT1 A 0 A_JumpIfInventory("RavagerPrimary",3,"Eject3")
	Goto Eject4
	
  Eject1:
	M6E1 A 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	TNT1 A 0 A_GunFlash("DeselectHand")
	M6E1 BCDE 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E1 A 0 A_PlaySoundEx("m60/clipout","SoundSlot5") // EJECT SOUND
	M6E1 FG 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E1 Z 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	BPSS A 0 A_FireCustomMissile("M60Shooter11",5,0,16,-3)
	Goto ReloadAnim
  Eject2:
	M6E2 A 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	TNT1 A 0 A_GunFlash("DeselectHand")
	M6E2 BCDE 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E2 A 0 A_PlaySoundEx("m60/clipout","SoundSlot5") // EJECT SOUND
	M6E2 FG 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E1 Z 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	BPSS A 0 A_FireCustomMissile("M60Shooter6",5,0,16,-3)
	Goto ReloadAnim
  Eject3:
	M6E3 A 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	TNT1 A 0 A_GunFlash("DeselectHand")
	M6E3 BCDE 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E3 A 0 A_PlaySoundEx("m60/clipout","SoundSlot5") // EJECT SOUND
	M6E3 FG 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6E1 Z 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	BPSS A 0 A_FireCustomMissile("M60Shooter3",5,0,16,-3)
	Goto ReloadAnim
  Eject4:
	TNT1 A 0 A_GunFlash("DeselectHand")
	M6E3 A 0 A_PlaySoundEx("m60/clipout","SoundSlot5") // EJECT SOUND
	M6E2 Z 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto ReloadAnim

//==========================================================
// -- RELOADING
//==========================================================

  ReloadAnim:
	M6R1 A 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 B 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 C 4 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 D 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 G 0 A_PlaySoundEx("m60/cliptoss","SoundSlot5") // EJECT SOUND
	M6R1 E 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 F 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 G 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 H 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 IJKLM 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 N 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 O 4 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 P 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 S 0 A_PlaySoundEx("m60/clipin","SoundSlot5") // EJECT SOUND
	Goto CalculateAmmo
	
  CalculateAmmo:
	 TNT1 A 0 A_JumpIfInventory("Perk_Commando",1,"CalculateAmmoPerk")
     TNT1 A 0 A_JumpIfInventory("RavagerSecondary",1,2)
	 Goto ReloadEnd
	 TNT1 AAA 0
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",100,"ReloadEnd")
	 TNT1 A 0 A_TakeInventory("RavagerSecondary",1)
	 TNT1 A 0 A_GiveInventory("RavagerPrimary",1)
	 Loop
	 
  CalculateAmmoPerk:
	 TNT1 A 0 A_JumpIfInventory("PerkLevel",10,"CalculateAmmoPerk10")
     TNT1 A 0 A_JumpIfInventory("RavagerSecondary",1,2)
	 Goto ReloadEnd
	 TNT1 AAA 0
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",125,"ReloadEnd")
	 TNT1 A 0 A_TakeInventory("RavagerSecondary",1)
	 TNT1 A 0 A_GiveInventory("RavagerPrimary",1)
	 Loop
	 
  CalculateAmmoPerk10:
     TNT1 A 0 A_JumpIfInventory("RavagerSecondary",1,2)
	 Goto ReloadEnd
	 TNT1 AAA 0
	 TNT1 A 0 A_JumpIfInventory("RavagerPrimary",150,"ReloadEnd")
	 TNT1 A 0 A_TakeInventory("RavagerSecondary",1)
	 TNT1 A 0 A_GiveInventory("RavagerPrimary",1)
	 Loop
	
  ReloadEnd:
	M6R1 QR 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 S 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 T 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 U 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 V 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R1 WXYZ 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 ABC 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 E 0 A_PlaySoundEx("m60/boltback","SoundSlot5") // EJECT SOUND
	M6R2 DE 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 FG 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 H 4 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 J 0 A_PlaySoundEx("m60/boltfwd","SoundSlot5") // EJECT SOUND
	M6R2 H 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 I 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 J 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 K 2 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 L 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 MNO 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	M6R2 P 0 A_GunFlash("SelectHand")
	M6R2 PQ 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
	Goto Ready

//==========================================================

   Spawn:
     HMGP A -1
     Stop
   }
}