ACTOR BaseZombieVar2
{
	Health 20
	Radius 20
	Height 38
	Speed 9
	PainChance 24
	PainChance "QuickMelee", 255
	PainChance "MeleeLeft", 255
	PainChance "MeleeRight", 255
	DamageFactor "head", 1.0
	DamageFactor "Decapitate", 1.0
	DamageFactor "Head_Shotgun", 1.15
	DamageFactor "ItemExplode", 0.00
	DamageFactor "MeleeLeft", 2.5
	DamageFactor "MeleeRight", 2.5
	DamageFactor "MeleeVert", 2.5
	Monster
	+FLOORCLIP
	+NOTARGET
	+NOINFIGHTING
	MaxDropOffHeight 512
	Mass 200
	SeeSound "trent/sight"
	PainSound "trent/pain"
	DeathSound "trent/death"
	ActiveSound "trent/idle"
	Obituary "%o was taken down by a naked zombie."
	States
	{
	Spawn:
		BSV2 A 0
		BSV2 A 0 A_JumpIfInventory("HasSpawnedHead",1,"Wandering")
		BSV2 A 0 ACS_ExecuteAlways(625,0,44,0,0)
		BSV2 A 0 ACS_ExecuteWithResult(49,0,0,0)
		BSV2 A 0 A_GiveInventory("HasSpawnedHead",1)
		Goto Wandering
	Wandering:
		BSV2 A 0 A_ChangeFlag("FLOAT",0)
		BSV2 A 0 A_Gravity
		BSV2 A 0 A_LookEx(0,0,2048,2048,100)
		BSV2 A 0 A_JumpIf(waterlevel == 3, "SwimWander")
		BSV2 AABB 7 A_Wander
		BSV2 A 0 A_LookEx(0,0,2048,2048,100)
		BSV2 A 0 A_JumpIf(waterlevel == 3, "SwimWander")
		BSV2 CCDD 7 A_Wander
		Loop
    //=============================================================
	// INCENDIARY
	//=============================================================
	Pain.Fire:
	Pain.Dragon:
	Death.Fire:
	DragonPain:
	Death.Dragon:
	FireDeath:
		TNT1 A 0 ACS_ExecuteAlways(72,0,1,30,10)
		BSV2 A 1
		TNT1 A 0 A_SpawnItemEx("Flaming_BaseZombie",0,0,0)
		Stop
	//=============================================================
	SwimWander:
		BSV2 A 0 A_ChangeFlag("FLOAT",1)
		BSV2 A 0 A_NoGravity
		BSV2 A 0 A_JumpIf(waterlevel < 3, "Wandering")
		BSV2 A 0 A_LookEx(0,0,2048,2048,100)
		POSS AABB 7 A_Wander
		BSV2 A 0 A_JumpIf(waterlevel < 3, "Wandering")
		BSV2 A 0 A_LookEx(0,0,2048,2048,100)
		POSS BBCC 7 A_Wander
		Loop
	See:
		BSV2 A 0 A_TakeInventory("Forgotten",18)
		BSV2 A 0 A_ChangeFlag("FLOAT",0)
		BSV2 A 0 A_Gravity
		BSV2 A 0 A_JumpIf(waterlevel == 3, "SwimSee")
		BSV2 AABB 3 A_Chase
		BSV2 A 0 A_JumpIf(waterlevel == 3, "SwimSee")
		BSV2 CCDD 3 A_Chase
		BSV2 A 0 A_JumpIfTargetInLOS(1)
		Goto ForgetTarget
		TNT1 A 0
		Goto See+1
	SwimSee:
		BSV2 A 0 A_TakeInventory("Forgotten",18)
		BSV2 A 0 A_ChangeFlag("FLOAT",1)
		BSV2 A 0 A_NoGravity
		BSV2 A 0 A_TakeInventory("Forgotten",18)
		BSV2 A 0 A_JumpIf(waterlevel < 3, "See")
		POSS AABB 3 A_Chase
		BSV2 A 0 A_JumpIf(waterlevel < 3, "See")
		POSS CCDD 3 A_Chase
		BSV2 A 0 A_JumpIfTargetInLOS(1)
		Goto ForgetTarget
		TNT1 A 0
		Goto SwimSee+1
	ForgetTarget:
		BSV2 A 0 A_GiveInventory("Forgotten",1)
		BSV2 A 0 A_JumpIfInventory("Forgotten",18,1)
		Goto See+1
		BSV2 A 0
		BSV2 A 0 A_TakeInventory("Forgotten",18)
		BSV2 A 0 A_ClearTarget
		Goto Wandering
	Melee:
		BSV2 E 8 A_FaceTarget
		BSV2 F 8 A_FaceTarget
		BSV2 G 6 A_CustomMeleeAttack(3 * random(1, 8), "imp/melee", "")
		Goto See
	Pain:
		BSV2 A 1
		BSV2 A 2 A_Pain
		Goto See
	Pain.QuickMelee:
		BSV2 A 0 A_FaceTarget
		BSV2 A 0 A_Recoil(10)
		BSV2 A 1
		BSV2 A 2 A_Pain
		Goto See
    Death.Decapitate:
    Death.head:
	Death.minorhead:
	Death.Head_Shotgun:
		TNT1 A 0 ACS_ExecuteAlways(72,0,1,35,15)
		TNT1 A 0 A_PlaySound("gore/juicy")
		TNT1 A 0 A_SpawnItemEx("HeadChunkSpawner",0,0,44)
		BSZO A 3
		BSZO B 3 A_NoBlocking
		BSZO CDEFG 3
		BSZO H 3
		BSZO I 1
		BSV2 I 0 A_SpawnItemEx("BaseZombieBodyHead",0,0,0)
		Stop
    Death.MeleeDecap:
		TNT1 A 0 ACS_ExecuteAlways(72,0,1,35,15)
		TNT1 A 0 A_PlaySound("gore/juicy")
		TNT1 A 0 A_SpawnItemEx("DecapChunkSpawner",0,0,44)
		BSZO A 3
		BSZO B 3 A_NoBlocking
		BSZO CDEFG 3
		BSZO H 3
		BSZO I 1
		BSV2 I 0 A_SpawnItemEx("BaseZombieBodyHead",0,0,0)
		Stop
	Death:
		TNT1 A 0 A_Jump(128,"Death2")
		TNT1 A 0 ACS_ExecuteAlways(72,0,0,30,10)
		BSV2 F 5 A_Scream
		BSV2 G 5 A_NoBlocking
		BSV2 H 5
		BSV2 I 5
		BSV2 L 1
		BSV2 I 0 A_SpawnItemEx("BaseZombieBody",0,0,0)
		Stop
    Death2:
		TNT1 A 0 ACS_ExecuteAlways(72,0,0,30,10)
		BSV2 T 3 A_Scream
		BSV2 U 3 A_NoBlocking
		BSV2 VWXYZ 3
		BSZN A 3
		BSZN B 1
		BSV2 I 0 A_SpawnItemEx("BaseZombieBody2",0,0,0)
		Stop
	Death.PointBlank:
	Death.ExplosiveDamage:
		BSV2 M 0 ACS_ExecuteAlways(72,0,1,35,10)
		TNT1 A 0 A_SpawnItemEx("GibChunkSpawner",0,0,32)
		BSV2 M 5
		BSV2 N 5 A_XScream
		BSV2 O 5 A_NoBlocking
		BSV2 PQR 5
		BSV2 S -1
		Stop
	Death.MeleeLeft:
	Death.MeleeRight:
		BZSP A 0 A_PlaySoundEx("gore/split","Body")
		BZSP A 0 A_Noblocking
		BZSP A 0 A_UnsetShootable
		TNT1 A 0 ACS_ExecuteAlways(72,0,0,30,10)
		TNT1 A 0 A_SpawnItemEx("GibSpawn_Splitter",0,0,30)
		TNT1 A 0 A_SpawnItemEx("Torso_BaseZombie",0,0,30,random(-1,1),random(-1,1),random(3,5))
		BZSP EFG 4
		BZSP H -1
		Stop
	}
}